millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

dev-qt/qttools: drop 6.10.0

Browse Source 
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
Ionen Wolkens 2025-11-22 08:09:56 -05:00
parent ea5b1a043d
commit 7379f1de35
No known key found for this signature in database
GPG Key ID: B24406B0B0AC4334
2 changed files with 0 additions and 108 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
dev-qt/qttools/Manifest
View File

@ -1,3 +1,2 @@
DIST qttools-everywhere-src-6.10.0.tar.xz 10035252 BLAKE2B 1370dd36c4f29140ed571c7fb8f26ee5a40efb1cdf143de500d90d53bc398fc096b42f88596af54dfdf22d43149d2eefd7d5707399e333feeffb62bde749a39f SHA512 48d5449b286d0f39ed2dc5f583965bfc40767b607e658f7139f185bdd96616854950fd317e46165ee031ec431cfd1ef0d0bce5824ec3149dcbcf3ac9683097ef
DIST qttools-everywhere-src-6.10.1.tar.xz 10047008 BLAKE2B 63674679449f21a8d3ac5771de934ab0ffb6bc27664f0c986ba143831cd800dcf6fea00f90149f737272b0893f76b540be4fa83604ad4b229d4d54620508cbd8 SHA512 887450ec1b7249ae49ecbebc279a81e67603d0399da73ab605f26d29863db06c8a519c3cf16495e9eb7bc8e8e1fe3b2650e1e54b414546ec6fad20b961a39627
DIST qttools-everywhere-src-6.9.3.tar.xz 10334740 BLAKE2B 55bdafdf8f162b0700f104afb3cc8532e217fed4f76e83a54ba8d7a62e202d75263cc14cbb7ba1e507a1a43213ad7d62b00adcad963d86681e5937e58b465553 SHA512 529aae86f9d4ba52b6ec1f72d19c611ce17c8e6644974cb1f202a5eef54f83167b072dfae9d94d29f0ab2269ba97a99bd7744b573b3dbd1aa2e40a55729242c0

107
dev-qt/qttools/qttools-6.10.0.ebuild
View File

@ -1,107 +0,0 @@
# Copyright 2021-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LLVM_COMPAT=( {17..21} ) # see .cmake.conf for minimum
LLVM_OPTIONAL=1
# behaves very badly when qttools is not already installed, also
# other issues to handle (clang tests flaky depending on version,
# and 3rdparty/ tries to FetchContent gtest)
QT6_RESTRICT_TESTS=1
inherit llvm-r2 optfeature qt6-build xdg
DESCRIPTION="Qt Tools Collection"
if [[ ${QT6_BUILD_TYPE} == release ]]; then
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
fi
IUSE="
+assistant designer distancefieldgenerator gles2-only +linguist
opengl pixeltool +qdbus qdoc qml qmlls qtattributionsscanner qtdiag
qtplugininfo vulkan +widgets zstd
"
# note that some tools do not *require* widgets but will skip a sub-tool
# if not enabled (e.g. linguist gives lrelease but not the GUI linguist6)
REQUIRED_USE="
assistant? ( widgets )
designer? ( qml widgets )
distancefieldgenerator? ( qml widgets )
pixeltool? ( widgets )
qdoc? ( qml ${LLVM_REQUIRED_USE} )
qmlls? ( assistant qml )
"
RDEPEND="
~dev-qt/qtbase-${PV}:6[widgets?]
assistant? ( ~dev-qt/qtbase-${PV}:6[concurrent,network,sql,sqlite] )
designer? (
~dev-qt/qtbase-${PV}:6[network,xml,zstd=]
zstd? ( app-arch/zstd:= )
)
qdbus? ( ~dev-qt/qtbase-${PV}:6[dbus,xml] )
qdoc? (
$(llvm_gen_dep '
llvm-core/clang:${LLVM_SLOT}=
llvm-core/llvm:${LLVM_SLOT}=
')
)
qml? ( ~dev-qt/qtdeclarative-${PV}:6[widgets?] )
qmlls? ( ~dev-qt/qtdeclarative-${PV}:6[qmlls] )
qtdiag? ( ~dev-qt/qtbase-${PV}:6[network,gles2-only=,vulkan=] )
widgets? ( ~dev-qt/qtbase-${PV}:6[opengl=] )
"
DEPEND="
${RDEPEND}
qtdiag? (
vulkan? ( dev-util/vulkan-headers )
)
"
src_prepare() {
qt6-build_src_prepare
# qttools is picky about clang versions and ignores LLVM_SLOT
sed -e '/find_package/s/${\(LLVM_\)*VERSION_CLEAN}//' \
-i cmake/FindWrapLibClang.cmake || die
}
src_configure() {
use qdoc && llvm_chost_setup
local mycmakeargs=(
# prevent the clang test as it can abort due to bug #916098
$(cmake_use_find_package qdoc WrapLibClang)
$(cmake_use_find_package qml Qt6Qml)
$(cmake_use_find_package widgets Qt6Widgets)
$(qt_feature assistant)
$(qt_feature designer)
$(qt_feature distancefieldgenerator)
$(qt_feature linguist)
$(qt_feature pixeltool)
$(qt_feature qdbus)
$(qt_feature qdoc)
$(qt_feature qtattributionsscanner)
$(qt_feature qtdiag)
$(qt_feature qtplugininfo)
$(usev widgets -DQT_INSTALL_XDG_DESKTOP_ENTRIES=ON)
# USE=qmlls' help plugin may be temporary, upstream has plans to split
# QtHelp into another package so that qtdeclarative can depend on it
# without a circular dependency with qttools
$(cmake_use_find_package qmlls Qt6QmlLSPrivate)
)
qt6-build_src_configure
}
pkg_postinst() {
xdg_pkg_postinst
use assistant &&
optfeature "Qt documentation viewable in assistant" \
'dev-qt/qt-docs:6[qch]' #602296
}