dev-python/isort: Bump to 6.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/isort/Manifest

@@ -1 +1,2 @@
 DIST isort-6.0.1.gh.tar.gz 827044 BLAKE2B bdde4a0bcc84dd444e86988c1d477c1701534d7b52db3ce8cf3d162b06ee9db2a1a705e7af3c149d2a6eac77363ce365e64895a931c3202c16cb6d31480974cb SHA512 0ca2d28b706e97c8e0bc22de58c737d551bef03326ff6aaa36f90ebc08a40d7e1d18a6068de2b2090b901231be2e6622ce5947bceb58803671dd30defe5a5ec8
+DIST isort-6.1.0.gh.tar.gz 828669 BLAKE2B b29c7d9327f6a36ed3841f5583011fc38416992a7778cfda80de0843c21af30c9ee7359d48da99f44bbb806523491e17c28761601b8ef9e4108d51bb1b04bb52 SHA512 f7991a5ed81bbd4a06835b28a537692c9482e8b83d72df0649a0dea79d7390169a2f68df68744440d7d0ef7c4cfad5468a1fb9ae03a6260f751f363d1b447172

dev-python/isort/isort-6.1.0.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} pypy3_11 )
+
+inherit distutils-r1
+
+DESCRIPTION="A python utility/library to sort imports"
+HOMEPAGE="
+	https://github.com/PyCQA/isort/
+	https://pypi.org/project/isort/
+"
+SRC_URI="
+	https://github.com/PyCQA/isort/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/black[${PYTHON_USEDEP}]
+		>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+EPYTEST_PLUGINS=( hypothesis pytest-mock )
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unbundle tomli
+	sed -i -e 's:from ._vendored ::' isort/settings.py || die
+	rm -r isort/_vendored || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	# Install necessary plugins
+	local p
+	for p in example*/; do
+		pushd "${p}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local EPYTEST_IGNORE=(
+		# Excluded from upstream's test script
+		tests/unit/test_deprecated_finders.py
+	)
+
+	if ! has_version "dev-python/pylama[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/unit/test_importable.py
+			tests/unit/test_pylama_isort.py
+		)
+	fi
+
+	epytest tests/unit
+}