kde-plasma/wacomtablet: 6.5.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-plasma/wacomtablet/Manifest

@@ -1 +1,2 @@
 DIST wacomtablet-6.4.5.tar.xz 840680 BLAKE2B b2bb9823aecd6fe5c2aaae14b10dccc5ab8e830b46548432d698a63a59bde3346969a55f72218713284315074aeeb209abe4d6fef8bb2b010210fe5e16ef30de SHA512 5094240cbf3fdec0c59feb21bb034c0e8dc0e12541fbf5c8366883db5b954f4036a3209a47a8471ca7eced5a6d7ffe0ba853b0bed5140101d28355fc009c37bd
+DIST wacomtablet-6.5.0.tar.xz 838708 BLAKE2B e563275d05ab17fd2703ea418430a4182f58abcd0547f9b9eadbf334aa205238540c9011765e6940ac4391d4651bac072c62e21a3619295b50d6f07bd5f52f4c SHA512 c727b24ceb3bed09007c392bf1b80dc9badb889f9d761535b5d713108748653a651a967b18a131fb494cfc78e6f513e88cf3a34b44668aedffac2b9889b46d6d

kde-plasma/wacomtablet/wacomtablet-6.5.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=6.18.0
+QTMIN=6.9.1
+inherit ecm plasma.kde.org xdg
+
+DESCRIPTION="Wacom system settings module that supports different button/pen layout profiles"
+HOMEPAGE="https://userbase.kde.org/Wacomtablet"
+
+LICENSE="GPL-2"
+SLOT="6"
+KEYWORDS="~amd64"
+IUSE=""
+
+# slot op: Uses Qt6::GuiPrivate for qtx11extras_p.h
+RDEPEND="
+	>=dev-libs/libwacom-0.30:=
+	>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-plasma/libplasma-${KDE_CATV}:6
+	>=kde-plasma/plasma5support-${KDE_CATV}:6
+	>=x11-drivers/xf86-input-wacom-0.20.0
+	x11-libs/libXi
+	x11-libs/libxcb
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+	x11-libs/libX11
+"
+BDEPEND="sys-devel/gettext"
+
+src_test() {
+	# test needs DBus, bug 675548
+	local myctestargs=(
+		-E "(Test.KDED.DBusTabletService)"
+	)
+
+	ecm_src_test
+}