net-libs/glib-networking: Version bump to 2.76_beta

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29968
Signed-off-by: Matt Turner <mattst88@gentoo.org>

net-libs/glib-networking/Manifest

@@ -1 +1,2 @@
 DIST glib-networking-2.74.0.tar.xz 277232 BLAKE2B d0027a3beff276b2d0b008d1ed0bdeef231d8fb03c26c2e301a3eaef76ad4b704a5db36f6265c5516d73c5dbdb98c7c0919b6924038506dad0123f5ec77577b2 SHA512 f266c106f2c9379b95773a852c1b5c62ae1d6a758d25c436c3558f620d8e0a211201b3c4dfd89cdbe28b88430bba0cca621e62c01ea23d473983e203919bb1e6
+DIST glib-networking-2.76.beta.tar.xz 280780 BLAKE2B d64d6de6e43405a16ff54dce5d27d8ca340338c4d8d7d0965f61b6219684e048911bfe1745eb637ddae7a7e8cdbf3122e5a241a50544ba10bf629f237c8b6c9e SHA512 8c5f77a76ae283247c079164c65cd91b7b2f6919efd89fd6393de2926b35845c83f153fab3b0b7ce4d60d0c9495f2f3dee3009fea3d94a69a8bb26337886233d

net-libs/glib-networking/glib-networking-2.76_beta.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson-multilib xdg
+
+DESCRIPTION="Network-related giomodules for glib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/glib-networking"
+SRC_URI="https://download.gnome.org/sources/${PN}/2.76/${PN}-2.76.beta.tar.xz"
+S="${WORKDIR}/${PN}-2.76.beta"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="+gnome +libproxy +ssl test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.73.3:2[${MULTILIB_USEDEP}]
+	libproxy? ( >=net-libs/libproxy-0.4.16:=[${MULTILIB_USEDEP}] )
+	>=net-libs/gnutls-3.7.4:=[${MULTILIB_USEDEP}]
+	ssl? ( app-misc/ca-certificates )
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+"
+DEPEND="${RDEPEND}
+	test? ( net-libs/gnutls[pkcs11] )
+"
+BDEPEND="
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( sys-apps/dbus )
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	if ! use test ; then
+		# Don't build tests unconditionally
+		# This is a hack to avoid needing gnutls[pkcs11] when USE=-test
+		# It may become a real runtime dependency in future
+		# Please check!
+		# bug #777462
+		sed -i "/^subdir('tests')/d" tls/meson.build || die
+	fi
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dgnutls=enabled
+		-Dopenssl=disabled
+		$(meson_feature !libproxy environment_proxy)
+		$(meson_feature libproxy)
+		$(meson_feature gnome gnome_proxy)
+		-Dinstalled_tests=false
+		-Ddebug_logs=false
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	multilib_pkg_postinst() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+
+	multilib_pkg_postrm() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postrm
+}