net-misc/seafile: Bump to 9.0.13

Closes: https://bugs.gentoo.org/952621
Signed-off-by: Z. Liu <zhixu.liu@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/40911
Signed-off-by: Sam James <sam@gentoo.org>

net-misc/seafile/Manifest

@@ -1 +1,2 @@
 DIST seafile-9.0.11.tar.gz 765322 BLAKE2B 7d82a919d64023b5d040e4a344da78b55568474900951c0e4ac4a7812436e501c09dd897d9746fa29b1a9b3deb737452258737b678f39a6d5c449770e0433258 SHA512 01f72387eed465a71d72b0a707d8edc1b2b4f758157e586d2c17bca9dc3001e7e9296d1addc2efaf0629ca318e233a2268e7cdf4b24de963e7030cb571d03a8e
+DIST seafile-9.0.13.tar.gz 767210 BLAKE2B 2aaaca2479553eae6e54bab7fdb14e7f2893f45959231c000d9d72bfd3837538faecd51dcdc861b19dceebae344cd4963f3dd8783857e7878fb6982e55b7d2f8 SHA512 c5bf41fc6812a49a9b0b45ff77c9ff3628a85005074f159b9b93bb8b4cde4ef79e7caf6de26cc1501e64c993dd9e6bb3411873db2c34665db6d05a82cdfd08ed

net-misc/seafile/seafile-9.0.13.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+# Upstream is moving tags repeatedly, then we use commit hash.
+RELEASE_COMMIT="bc71a5876e27a3810f3917fba1493d7487eb3876"
+
+inherit autotools python-single-r1 vala
+
+DESCRIPTION="File syncing and sharing software with file encryption and group sharing"
+HOMEPAGE="https://www.seafile.com/ https://github.com/haiwen/seafile/"
+SRC_URI="https://github.com/haiwen/${PN}/archive/${RELEASE_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${RELEASE_COMMIT}"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	app-crypt/argon2:=
+	dev-libs/openssl:=
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/jansson:=
+	dev-libs/libevent:=
+	net-libs/libsearpc[${PYTHON_SINGLE_USEDEP}]
+	net-libs/libwebsockets:=[client]
+	net-misc/curl
+	sys-apps/util-linux
+	sys-libs/zlib
+	elibc_musl? ( sys-libs/fts-standalone )"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	$(vala_depend)"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	vala_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# Remove unnecessary .la files
+	find "${ED}" -name '*.la' -delete || die
+	python_fix_shebang "${ED}"/usr/bin/seaf-cli
+}