dev-python/paramiko: Bump to 4.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/paramiko/Manifest

@@ -1 +1,2 @@
 DIST paramiko-3.5.1.gh.tar.gz 376472 BLAKE2B e00c0e1ab62eb443b3dfb5b1ebfacb9ac2f0f7e4946dcb986f8a211c22e645acd6d96ceaf709a954bf1f1554e8ce57ea1c6269984184025de39d9d9c4ff909d9 SHA512 a1198f7f21cfbdbb843acb59cc431f9af0a47d687a7e9702244f36b555bb37b75149c0e22302040400f20df50dee1d83154e5acd582982ca44f6cf68ff592675
+DIST paramiko-4.0.0.gh.tar.gz 430056 BLAKE2B 2fc4843de770d824928489284d65bb9a6d87efaa185ba5a2e1c8951a8985ca8c535f89a3a5f7d3745119a8fdf142fc7e8655c6ef44965e55c95b7db1cf567144 SHA512 5a6d4cf000f13e1a9ee2558f18a942e3b7f334807b007bed77cfb9d50f15d423b3490a0deca08f82749391092d2514c44cd7d8dda2dc66436db3816c2501c72a

dev-python/paramiko/paramiko-4.0.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="SSH2 protocol library"
+HOMEPAGE="
+	https://www.paramiko.org/
+	https://github.com/paramiko/paramiko/
+	https://pypi.org/project/paramiko/
+"
+SRC_URI="
+	https://github.com/paramiko/paramiko/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples server"
+
+RDEPEND="
+	>=dev-python/bcrypt-3.2[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3[${PYTHON_USEDEP}]
+	>=dev-python/pynacl-1.5[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=5
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# upstream doesn't really maintain the gssapi support
+	tests/test_gssapi.py
+	tests/test_kex_gss.py
+	tests/test_ssh_gss.py
+)
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/${PN}-3.2.0-nih-test-deps.patch"
+	)
+
+	if ! use server; then
+		PATCHES+=( "${FILESDIR}/${PN}-3.2.0-disable-server.patch" )
+	fi
+
+	distutils-r1_src_prepare
+
+	# optional dep
+	sed -i -e '/invoke/d' pyproject.toml || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc -r demos/*
+	fi
+}