dev-libs/log4cplus: Backport IUSE qt6 from upstream git master

Patchset complete (but only) with CMake bits and pieces. Tests pass.

Source (upstream):
https://github.com/log4cplus/log4cplus/pull/653

Closes: https://bugs.gentoo.org/959818
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

dev-libs/log4cplus/Manifest

@@ -1 +1,2 @@
+DIST log4cplus-2.1.2-qt6.tar.xz 7412 BLAKE2B 9cdef29d57b204bf1390e092ed411f39debd33b490c0a13eca6c5e6bae568a3a2448128e032edbe15e188bcc63f8ed9db56bc3169046bc31efa126904d0111cb SHA512 8f19973685fbb0306a36ac18f457893e67f0e7bc4a722ffc65d2723630201fb7de4f6f454da8238bc798251c2b327b76d4416105d1bd000b818f52ada7b67d49
 DIST log4cplus-2.1.2.tar.xz 953200 BLAKE2B ea061affc3f789a7f4a00577551fccc079c57a2c139d388115c652a19a0825a82da35418267ba5c4818843e0a39b147f50dd4a41a19e31de9e0b8fda873fe20d SHA512 d6285e4964e8eda072b61e0585d5fe08c1d942b688752baf75ba230d49691070156ab4da1803d82d0c09128bcb87e21910e38ee9441df13ff762d527fe431444

dev-libs/log4cplus/log4cplus-2.1.2-r1.ebuild

@@ -0,0 +1,41 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PATCHSET="${P}-qt6.tar.xz"
+inherit cmake
+
+DESCRIPTION="C++ port of the Log for Java (log4j) logging library"
+HOMEPAGE="https://log4cplus.sourceforge.io/ https://github.com/log4cplus/log4cplus"
+SRC_URI="https://downloads.sourceforge.net/project/${PN}/${PN}-stable/${PV}/${P}.tar.xz
+	https://dev.gentoo.org/~asturm/distfiles/${PATCHSET}"
+
+LICENSE="|| ( Apache-2.0 BSD-2 )"
+SLOT="0/9"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="explicit-initialization iconv qt6 server test threads"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	iconv? ( virtual/libiconv )
+	qt6? ( dev-qt/qtbase:6 )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${WORKDIR}"/${PATCHSET/.tar.xz/} )
+
+src_configure() {
+	local mycmakeargs=(
+		-DLOG4CPLUS_BUILD_LOGGINGSERVER=$(usex server)
+		-DWITH_UNIT_TESTS=$(usex test)
+		-DLOG4CPLUS_BUILD_TESTING=$(usex test)
+		-DLOG4CPLUS_ENABLE_THREAD_POOL=$(usex threads)
+		-DLOG4CPLUS_REQUIRE_EXPLICIT_INITIALIZATION=$(usex explicit-initialization)
+		-DWITH_ICONV=$(usex iconv)
+		-DLOG4CPLUS_QT5=OFF
+		-DLOG4CPLUS_QT6=$(usex qt6)
+	)
+
+	cmake_src_configure
+}