sci-mathematics/clipper2: add 1.5.2

Closes: https://bugs.gentoo.org/943720
Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/41967
Signed-off-by: Sam James <sam@gentoo.org>

sci-mathematics/clipper2/Manifest

@@ -1 +1,2 @@
 DIST Clipper2_1.4.0.tar.gz 600352 BLAKE2B 0ba268ba691fde4aef456d8f6ef1810a8c13b77c5bb932296b11b5f0d96dfe70f2d617d7ba013f85817dbc01a800d0ab1fba566e4ab56efde6541c00f3d7f359 SHA512 91036e81244f3615095d7cd8522f9c4a32ea66f802e3d190393eb8939e1a706b69c69c3a5b7c6522235c075dd6ecd45f21bffb47448ba72191ddcf05e9e93128
+DIST Clipper2_1.5.2.tar.gz 620852 BLAKE2B 639943509f3e1b27c7e26e7ca2a6b14afd32654d7d43900e2f5eb6db83c2c48af17c14aa35a99a6dc679d5015f5378d56bc600ff3a9250dcf1d690d11789f751 SHA512 0d885c5e38906fdc64c915a1cabbd37dc3d752d8c8988100f5f9af79234c3634254c0f61e931cc8bb0cec1f3404aba63be61e6cfcb00b177a3d75c415680fbd2

sci-mathematics/clipper2/clipper2-1.4.0.ebuild

@@ -6,7 +6,7 @@ EAPI=8
 MY_PN="Clipper2"
 MY_P=${MY_PN}_${PV}
 
-inherit cmake
+inherit cmake flag-o-matic
 
 DESCRIPTION="Polygon Clipping and Offsetting"
 HOMEPAGE="https://www.angusj.com/clipper2/Docs/Overview.htm"
@@ -24,7 +24,17 @@ DEPEND="
 	test? ( dev-cpp/gtest )
 "
 
+src_prepare() {
+	cmake_src_prepare
+
+	#943720
+	sed -e 's/ -Werror//g' -i CMakeLists.txt || die
+}
+
 src_configure() {
+	append-flags -fno-strict-aliasing
+	filter-lto
+
 	local mycmakeargs=(
 		-DCLIPPER2_UTILS="no"
 		-DCLIPPER2_EXAMPLES="no"

sci-mathematics/clipper2/clipper2-1.5.2.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="Clipper2"
+MY_P=${MY_PN}_${PV}
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Polygon Clipping and Offsetting"
+HOMEPAGE="https://www.angusj.com/clipper2/Docs/Overview.htm"
+SRC_URI="https://github.com/AngusJohnson/Clipper2/archive/refs/tags/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${MY_P}/CPP"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? ( dev-cpp/gtest )
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	#943720
+	sed -e 's/ -Werror//g' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	local mycmakeargs=(
+		-DCLIPPER2_UTILS="no"
+		-DCLIPPER2_EXAMPLES="no"
+		-DCLIPPER2_TESTS="$(usex test)"
+		-DCLIPPER2_USINGZ="no"  # manifold src/third_party/CMakeLists.txt
+
+		-DUSE_EXTERNAL_GTEST="yes"
+	)
+	cmake_src_configure
+}