millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-09 00:07:57 +03:00
Code Issues Packages Projects Releases Wiki Activity

net-wireless/urh: add 2.9.8_p20251123 supports Qt6

Browse Source 
Backport of 2.9.8 onto the older qt6 branch (see
https://bugs.gentoo.org/965506)

Closes: https://bugs.gentoo.org/965506
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>
This commit is contained in:
Thomas Beierlein 2025-12-02 11:02:52 +01:00
parent 94421a3998
commit c0bcdc5319
No known key found for this signature in database
GPG Key ID: AF4C8CF6B6C40570
2 changed files with 77 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
net-wireless/urh/Manifest
View File

@ -1 +1,2 @@
DIST urh-2.9.8.gh.tar.gz 13436054 BLAKE2B efc106fc1ef4879a0cebfe65e120dd4789576264b853b02b7ecf4065b9feeba26428b696a388298e2904e084302eed8b049f5f6d2c9a205730a9726d39c505e9 SHA512 a5327bee699bba8e6ffef2e7ec54f5f4b354feda18340c9b567b10b8c9283c5c907a546fd8a5660a2c325d42b8928cb9592630d0c2a5ed7dfdcf5dc434be4cb2
DIST urh-2.9.8_p20251123.tgz 14465110 BLAKE2B b976581832048b2e0c848d3cc23e2d1dcae0c6369e12c27954483ad75101a89b3eb8beb5dfb33cc6564d0c0a1a2f16cee4039f9c47adc6d20a3a3ef0060fbf69 SHA512 42e78cc57d62c44fc7a8beb9e4dc84c4de2c08d8c4488b4a49e05c9796d7cb82fc3958db60d3dd65e03c29215c3b27d8df349ff967410e2c90e7f87869081a66

76
net-wireless/urh/urh-2.9.8_p20251123.ebuild Normal file
View File

@ -0,0 +1,76 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1 virtualx
DESCRIPTION="Universal Radio Hacker: investigate wireless protocols like a boss"
HOMEPAGE="https://github.com/jopohl/urh"
# backported onto older Qt6 branch (see https://github.com/jopohl/urh/pull/1072)
SRC_URI="https://dev.gentoo.org/~tomjbe/distfiles/${P}.tgz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="airspy audio bladerf hackrf limesdr plutosdr rtlsdr sdrplay uhd"
DEPEND="${PYTHON_DEPS}
net-wireless/gnuradio[zeromq]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
dev-python/pyzmq[${PYTHON_USEDEP}]
dev-python/cython[${PYTHON_USEDEP}]
airspy? ( net-wireless/airspy:= )
audio? ( dev-python/pyaudio[${PYTHON_USEDEP}] )
bladerf? ( net-wireless/bladerf:= )
hackrf? ( net-libs/libhackrf:= )
limesdr? ( net-wireless/limesuite )
plutosdr? ( net-libs/libiio:= )
rtlsdr? ( net-wireless/rtl-sdr:= )
sdrplay? ( <net-wireless/sdrplay-3.0.0:= )
uhd? ( net-wireless/uhd:= )"
RDEPEND="${DEPEND}
dev-python/pyqt6[${PYTHON_USEDEP},testlib]
net-wireless/gr-osmosdr"
distutils_enable_tests pytest
PATCHES=( "${FILESDIR}/${PN}-2.9.7-no-numpy-setup.patch" )
python_configure_all() {
DISTUTILS_ARGS=(
$(use_with airspy)
$(use_with bladerf)
$(use_with hackrf)
$(use_with limesdr)
$(use_with plutosdr)
$(use_with rtlsdr)
$(use_with sdrplay)
$(use_with uhd usrp)
)
}
src_test() {
virtx distutils-r1_src_test
}
python_test() {
# Why are these disabled?
# import errors AND hangs forever after 'tests/test_spectrogram.py::TestSpectrogram::test_cancel_filtering'
# import errors 'tests/test_continuous_modulator.py::TestContinuousModulator::test_modulate_continuously'
# import errors 'tests/test_send_recv_dialog_gui.py::TestSendRecvDialog::test_continuous_send_dialog'
# import errors 'tests/test_spectrogram.py::TestSpectrogram::test_channel_separation_with_negative_frequency'
local EPYTEST_DESELECT=(
'tests/test_spectrogram.py::TestSpectrogram::test_cancel_filtering'
'tests/test_continuous_modulator.py::TestContinuousModulator::test_modulate_continuously'
'tests/test_send_recv_dialog_gui.py::TestSendRecvDialog::test_continuous_send_dialog'
'tests/test_spectrogram.py::TestSpectrogram::test_channel_separation_with_negative_frequency'
)
cd "${T}" || die
epytest -s --pyargs urh.cythonext "${S}/tests" || die
}