x11-misc/libinput-gestures: add 2.80, python 3.13

Closes: https://bugs.gentoo.org/948613
Closes: https://bugs.gentoo.org/952768
Signed-off-by: Vladimir Pavljuchenkov <spiderx@spiderx.dp.ua>
Part-of: https://github.com/gentoo/gentoo/pull/41092
Closes: https://github.com/gentoo/gentoo/pull/41092
Signed-off-by: Sam James <sam@gentoo.org>

x11-misc/libinput-gestures/Manifest

@@ -1 +1,2 @@
 DIST libinput-gestures-2.76.tar.gz 28913 BLAKE2B d1c610af1eaf48170c08bea1eb92ce3cc36efc8f8035ea5f00cdf151bfe5c8d14368e4a37f8eb9cca7e59742136ba65909c9a468ba254a78d35dcaba7500ce62 SHA512 001c6c64e9ca52b4a7453837448803c797cc746fac04ad15613aa20a6bb33c44b441c343dfa56f23fa195fc7216a6d6c00a88f13e39481a12654a3a1a6dbdd98
+DIST libinput-gestures-2.80.tar.gz 31583 BLAKE2B a0548352d5b94e4f4f6b2d28f3d30bb99b0250c7451bec40f98ff9ea2d2d89c3a3eab1fb884cda9fe438935033875304d78dd5cd85986b9c5501eb8b05efd443 SHA512 717415dbc9c99e1f53847ebea5c57813a74ea0c9d8f5b112c74b4cdfe143e661eb63088ffc47ceee1acf41506172d327c39b95e8db4727503b2fb9fdf54d9c01

x11-misc/libinput-gestures/libinput-gestures-2.80.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..14} python3_{13..14}t )
+
+inherit python-single-r1 xdg
+
+DESCRIPTION="Actions gestures on your touchpad using libinput"
+HOMEPAGE="https://github.com/bulletmark/libinput-gestures"
+SRC_URI="https://github.com/bulletmark/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="experimental"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/libinput
+	x11-misc/wmctrl
+	x11-misc/xdotool"
+DEPEND="dev-libs/libinput
+	dev-util/desktop-file-utils"
+
+src_prepare() {
+	default
+
+	use experimental && eapply "${FILESDIR}/${PN}"-2.76-zombie.patch
+
+	# Fix docdir installation path
+	sed -i "/^DOCDIR/s@\$NAME@${PF}@" libinput-gestures-setup \
+		|| die "sed failed for libinput-gestures-setup"
+}
+
+src_compile() { :; }
+
+src_test() {
+	emake test
+}
+
+src_install() {
+	default
+	# Actually respect the python target setting
+	python_doscript "${PN}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	elog "You must be in the input group to read the touchpad device."
+
+	if ! has_version x11-libs/gtk+:3 ; then
+		elog "${PN}-setup script supports GNOME via x11-libs/gtk+:3."
+	fi
+	if ! has_version kde-plasma/kde-cli-tools:6 ; then
+		elog "${PN}-setup script supports Plasma via kde-plasma/kde-cli-tools:6."
+	fi
+}