millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

kde-misc/tellico: add 4.1.4

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner 2025-10-30 11:54:43 +01:00
parent af02fb9ba0
commit c817cdc812
No known key found for this signature in database
GPG Key ID: AE591BBC73E4DD5E
2 changed files with 87 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
kde-misc/tellico/Manifest
View File

@ -1 +1,2 @@
DIST tellico-4.1.3.tar.xz 6849524 BLAKE2B 8d1910eac8bb9cec5432924a607c2118ed2f82e271a1e964c29c797215222caf86d11cbe2f0ba2130d8b8d1ba436eb5426b475c1c1a18598e39cfa842019e6c5 SHA512 646560b933cd09f2ad7477c42684ae523b2a0abc0fd0d2192b128073ca545bdd0a104b6393d4d29f792d9d4437196a1601f33cc900995bafb89158927cce26aa
DIST tellico-4.1.4.tar.xz 6874740 BLAKE2B 576b1499c3facd294e0e84a82a7261c11a0bb76a1b0363a17b30d6310b6493fc95ef2b2aa1135e9df34bd222f68c9ecd00d7b17d73e8a80556e5c39416be2590 SHA512 0b69444ba3df0b1d8fdf75f7483e26b4dbd84fdd67f00c0484dc12575eb4d73d9716d6ec642c8f60e46151fe7f6ae4e981a0be6481432b538679a867b37b17d9

86
kde-misc/tellico/tellico-4.1.4.ebuild Normal file
View File

@ -0,0 +1,86 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="forceoptional"
KFMIN=6.9.0
QTMIN=6.7.2
inherit ecm kde.org xdg
DESCRIPTION="Collection manager based on KDE Frameworks"
HOMEPAGE="https://tellico-project.org/"
if [[ ${KDE_BUILD_TYPE} != live ]]; then
SRC_URI="https://tellico-project.org/files/${P}.tar.xz"
KEYWORDS="~amd64 ~arm64"
fi
LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
IUSE="bibtex cddb discid pdf scanner semantic-desktop taglib v4l xmp yaz"
# tests need network access
RESTRICT="test"
DEPEND="
dev-libs/libxml2:=
dev-libs/libxslt
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
>=dev-qt/qtcharts-${QTMIN}:6
>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
>=kde-frameworks/karchive-${KFMIN}:6
>=kde-frameworks/kcodecs-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/knewstuff-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
>=kde-frameworks/sonnet-${KFMIN}:6
bibtex? ( >=dev-perl/Text-BibTeX-0.780.0-r1 )
cddb? ( kde-apps/libkcddb:6 )
discid? ( dev-libs/libcdio:= )
pdf? ( app-text/poppler[qt6] )
scanner? ( kde-apps/libksane:6 )
semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:6 )
taglib? ( >=media-libs/taglib-1.5:= )
v4l? ( >=media-libs/libv4l-0.8.3 )
xmp? ( >=media-libs/exempi-2:= )
yaz? ( >=dev-libs/yaz-2:0= )
"
RDEPEND="${DEPEND}
!${CATEGORY}/${PN}:5
"
BDEPEND="sys-devel/gettext"
src_configure() {
local mycmakeargs=(
-DCMAKE_DISABLE_FIND_PACKAGE_Csv=ON
-DENABLE_BTPARSE=$(usex bibtex)
$(cmake_use_find_package cddb KCddb6)
$(cmake_use_find_package discid CDIO)
$(cmake_use_find_package pdf Poppler)
$(cmake_use_find_package scanner KSaneWidgets6)
$(cmake_use_find_package semantic-desktop KF6FileMetaData)
$(cmake_use_find_package taglib Taglib)
-DENABLE_WEBCAM=$(usex v4l)
$(cmake_use_find_package xmp Exempi)
$(cmake_use_find_package yaz Yaz)
)
ecm_src_configure
}