dev-python/openstacksdk: Bump to 4.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/openstacksdk/Manifest

@@ -1 +1,2 @@
 DIST openstacksdk-4.7.1.tar.gz 1297628 BLAKE2B 60c028354e21b82c3a9bfc0db339729e6a96c925ae514927caec1ca46f435737d4c83d6219e1af892525ea5ca9a68fa0f09e2fd53d4b591554ce7bf3ac995417 SHA512 0319cbd9b53d117b212d2659ae4d11b5fce7f2d5f501c518e93e3c7bed10eb768bbc8eccf7b4a558b957de59a1ebda59582102fb7f107a966aa2b70b5702a6be
+DIST openstacksdk-4.8.0.tar.gz 1309981 BLAKE2B 41b047b7e120c72cec8555daa7910870ca6f3ca56a14865e5f684d0754500728fc38974a25664b4aecb21bf37e5b06fdd8755dc13a88bbaa0fe4830903dc1db9 SHA512 993476e818648244c091f3b26bf9d532346859014de353bf45869531325c0c67ac66d1493be38c02389f51991c134ea87342ce89cc57073a8b9f62e606f108f1

dev-python/openstacksdk/openstacksdk-4.8.0.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-2.7[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.21[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-5.10.0[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus-client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.12.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+	sed -e 's:test_servers:_&:' \
+		-i openstack/tests/unit/test_stats.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	# fragile warning-based tests
+	sed -e 's:test_unsupported_version_override:_&:' \
+		-i openstack/tests/unit/test_missing_version.py || die
+	sed -e 's:test_create_unknown_proxy:_&:' \
+		-i openstack/tests/unit/test_connection.py || die
+
+	# stupid test checking if they pin to the newest os-service-types,
+	# except they don't actually do
+	sed -e 's:test_ost_version:_&:' \
+		-i openstack/tests/unit/test_utils.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}