millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

dev-python/python-lsp-server: Bump to 1.14.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-12-06 19:04:43 +01:00
parent 641a2f56cd
commit e4120a9690
No known key found for this signature in database
GPG Key ID: 8E32347AF4055AE8
2 changed files with 90 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/python-lsp-server/Manifest
View File

@ -1,2 +1,3 @@
DIST python_lsp_server-1.13.1.tar.gz 120484 BLAKE2B f07ed8546e4e1691a4fc03ead5bc4834755bee12fbe34abda3ec460a2ca261c3c7a14a98194ad085f217af1369bfc878b696770e2c8adb43135808dd196ade13 SHA512 9a8ef547a0d8383eace9aa0efeb83fca9852f3fc79676397c428508a3d8d90c045da7e4c98c9ff34016e9da6a41181e4dc1c881d2262856c9dfd4921f9a35d9a
DIST python_lsp_server-1.13.2.tar.gz 120665 BLAKE2B c45d7775f8af055f4b4e084e1ed6dbbf5a8788155691e04a742cb9494231ce7f8f80fb8fb01041edb7540f6d8fa0bd44187ef68a2cf3246c50808ac13905449d SHA512 0be67a934dd700346227e17e6b695c4e593d04dc82b49153868617a81af949a9ee11b4ada5dffe031c64d1dbfc4d1864c4d9dbf94ade0be606abef8eb8b2eaaf
DIST python_lsp_server-1.14.0.tar.gz 121536 BLAKE2B 207d43b758d6bb75070ac88174d483d9347593ca2b5cbe9fc724f916d73654e6907aced7e6fb19e339740b09d0ea3dc1e2bc18f7610ea2984f8c29cd441c92ad SHA512 6362bb87a1fc75751a37c42a899377bc420daa0bed4aa7206e956b41e09495a9d949820bcf789508ebe5b5646c6c1af8dba753b7cef06891c46b8ebed80d51dc

89
dev-python/python-lsp-server/python-lsp-server-1.14.0.ebuild Normal file
View File

@ -0,0 +1,89 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} )
inherit distutils-r1 optfeature pypi
DESCRIPTION="Python Language Server for the Language Server Protocol"
HOMEPAGE="
https://github.com/python-lsp/python-lsp-server/
https://pypi.org/project/python-lsp-server/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="all-plugins"
PLUGIN_DEP="
>=dev-python/autopep8-2.0.4[${PYTHON_USEDEP}]
>=dev-python/flake8-7.1[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
>=dev-python/pycodestyle-2.12.0[${PYTHON_USEDEP}]
>=dev-python/pyflakes-3.2.0[${PYTHON_USEDEP}]
>=dev-python/pylint-3.1[${PYTHON_USEDEP}]
>=dev-python/rope-1.11.0[${PYTHON_USEDEP}]
>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
"
RDEPEND="
dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
>=dev-python/python-lsp-jsonrpc-1.1.0[${PYTHON_USEDEP}]
dev-python/pluggy[${PYTHON_USEDEP}]
all-plugins? (
${PLUGIN_DEP}
)
"
BDEPEND="
test? (
${PLUGIN_DEP}
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pandas[${PYTHON_USEDEP}]
dev-python/qtpy[gui,testlib,${PYTHON_USEDEP}]
>=dev-python/websockets-10.3[${PYTHON_USEDEP}]
)
"
# Note: xdist breaks some tests
EPYTEST_PLUGINS=()
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# broken by presence of pathlib2
'test/plugins/test_autoimport.py'
# Requires pyqt5
'test/plugins/test_completion.py::test_pyqt_completion'
# TODO: fails on teardown; also hangs the test suite
test/test_language_server.py::test_missing_message
)
EPYTEST_IGNORE=(
# pydocstyle is archived upstream and broken with py3.12
test/plugins/test_pydocstyle_lint.py
)
python_prepare_all() {
# remove pytest-cov dep
sed -i -e '/addopts =/d' pyproject.toml || die
# unpin all the deps
sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
distutils-r1_python_prepare_all
}
pkg_postinst() {
optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
optfeature "Python docstring style checker" dev-python/pydocstyle
optfeature "Passive checker for Python programs" dev-python/pyflakes
optfeature "Python code static checker" dev-python/pylint
optfeature "Python refactoring library" dev-python/rope
optfeature "A formatter for Python files" dev-python/yapf
}