sci-mathematics/opensmt: bump to 2.5.1

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

sci-mathematics/opensmt/Manifest

@@ -1 +1,2 @@
 DIST opensmt-2.5.0.tar.gz 1940493 BLAKE2B ee643815b9da8bdc4a3a074a438eacdfde778347f4090aa7403e34859a9d51a17db8992c38a0e9f7a808384b0413abfbe2aa7b360dda44181344528159666945 SHA512 d70972eae376b927694f893ff9b6e4bfba7d0cfffe63545b5a0d582b594c3538643c9ae0121e75cf85aec3876eb4a45df2766c3a7700d07da05d1d6081953f42
+DIST opensmt-2.5.1.tar.gz 1943888 BLAKE2B 17b58fc3e693e77ce70835820f7361db9efe1cac561f1fa3480a839fbdf003d2566617cd97a3e2772ad8e890356b6a5761457779c0ac3b0841c2df6aee74946e SHA512 359ff968d7dbd8d94d6c5687d5b84e19c47016df5b1c0d80374743b395b6257cb4b97aa354b264103bd19c522f55912f1c938e646daf37f6b413488db917fc61

sci-mathematics/opensmt/opensmt-2.5.1.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Compact and open-source SMT-solver written in C++"
+HOMEPAGE="http://verify.inf.usi.ch/opensmt/
+	https://github.com/usi-verification-and-security/opensmt/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/usi-verification-and-security/${PN}.git"
+else
+	SRC_URI="https://github.com/usi-verification-and-security/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+IUSE="debug libedit +readline test"
+REQUIRED_USE="?? ( libedit readline )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/gmp:=[cxx]
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	test? ( dev-cpp/gtest )
+"
+
+# PATCHES=( "${FILESDIR}"/${PN}-2.4.3-musl.patch )
+
+src_prepare() {
+	cmake_src_prepare
+
+	echo "add_subdirectory(unit)" > "${S}"/test/CMakeLists.txt || die
+}
+
+src_configure() {
+	local CMAKE_BUILD_TYPE
+	if use debug ; then
+		CMAKE_BUILD_TYPE=Debug
+	else
+		CMAKE_BUILD_TYPE=Release
+	fi
+
+	local -a mycmakeargs=(
+		-DPACKAGE_TESTS=$(usex test)
+		-DUSE_READLINE=$(usex readline)
+	)
+	if use readline || use libedit ; then
+		mycmakeargs+=( -DENABLE_LINE_EDITING=ON )
+	fi
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm "${ED}"/usr/lib/libopensmt.a || die
+	dodir /usr/$(get_libdir)
+	mv "${ED}"/usr/lib/libopensmt.* "${ED}"/usr/$(get_libdir)/ || die
+}