sci-mathematics/opensmt: bump to 2.9.2

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

sci-mathematics/opensmt/Manifest

@@ -1 +1,2 @@
 DIST opensmt-2.7.0.gh.tar.gz 1532323 BLAKE2B 5d51d4919adbdd6be38348524820a05804ccd05f2caf637cc238fd220f88fec6926098d7905ddf3e00c6874286cee788301b98b9b71bf9c7e3ae5d80d4e1dd2d SHA512 15b87a9a9a9b55f63086ea10f6da75d8f8e86e71b46aff36efb28a49abb293a28e5e71a8d0e52d347112b8d4b3c045c884dbb1179f148e4da9a72e25f445001f
+DIST opensmt-2.9.2.gh.tar.gz 1462738 BLAKE2B 343ce5f1a48e2b27619a5c1fce12786ea17f4629be9dbccc917b9f58295c1cff1f4ebcddc15ad7acb079055ac42b855517156ac448c84e9b7f53b30c42a5f9a5 SHA512 19fda1642768ab0b42cfc0157c94e96d35fd55c393fcabb83e7eeaf4bf91e24ac93bf4a0668ff2574fe662ef3c6f6cd40191398cfabae55314cd2355d44f9d3f

sci-mathematics/opensmt/opensmt-2.9.2.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Compact and open-source SMT-solver written in C++"
+HOMEPAGE="http://verify.inf.usi.ch/opensmt/
+	https://github.com/usi-verification-and-security/opensmt/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/usi-verification-and-security/${PN}"
+else
+	SRC_URI="https://github.com/usi-verification-and-security/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+IUSE="debug libedit test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/gmp:=[cxx]
+	libedit? ( dev-libs/libedit:= )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	app-alternatives/yacc
+	app-alternatives/lex
+	test? ( dev-cpp/gtest )
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	echo "add_subdirectory(unit)" > "${S}/test/CMakeLists.txt" || die
+}
+
+src_configure() {
+	local CMAKE_BUILD_TYPE=""
+	if use debug ; then
+		CMAKE_BUILD_TYPE="Debug"
+	else
+		CMAKE_BUILD_TYPE="Release"
+	fi
+
+	local -a mycmakeargs=(
+		-DENABLE_LINE_EDITING="$(usex libedit)"
+		-DPACKAGE_TESTS="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use elibc_glibc ; then
+		dolib.so "${ED}/usr/lib/libopensmt.so"*
+		rm "${ED}/usr/lib/libopensmt.so"* || die
+	fi
+
+	rm "${ED}/usr/lib/libopensmt.a" || die
+}