millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-06 00:05:54 +03:00
Code Packages Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 6.69.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-03-16 04:08:35 +01:00
parent 921737138f
commit e80a1d559a
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -1,3 +1,4 @@
DIST hypothesis-6.68.0.gh.tar.gz 9350032 BLAKE2B c122455b7f941eaba8b37b7c4bd4760b2ea0d7c5cf3e973544b80edfa17ea13870c9c5121a121178850154f0058e55c4051ff0ea98d35d3c312468202108a04d SHA512 7ca3e79c1c5e091ae829244e1f6b3563c61add0a5bbe7a7b254df85191778a4b05a21f82ca3f50ba6e77a5ec5c9ec06d7dd15c6cf423c1a2eb524a2aeb3f2c91
DIST hypothesis-6.68.1.gh.tar.gz 9350091 BLAKE2B 5d6d6912b20d3badca440b668838f456239653c393d8f148ba5dd16227e078586167f0d7ff0adbdca0efe2a81ff27e0307d97b63492658dc28c9abd7c7691551 SHA512 6dbaefa411f7945081158b7d730dc1893dfe02ec4b45f7bdd645f6f2198d39b3f4313d1e18dbe9a82d13e36df5bc541f1b31539128f9de5480b82b916bd74c0c
DIST hypothesis-6.68.2.gh.tar.gz 9350253 BLAKE2B 5f98aac845a2f4e1dd9f54809d3e7e1b201bdecdec1c5c9cff10a37851af7d8d9e8cb643c1a9b0545672862b3639a17aed5f4197653d48d3114edd0105668307 SHA512 c3507f99376af924e375c51e0d56d4e444204d2ebe147d813a3f33a69594f83493c499714567b127556ea620df7bde58f4a1ba662bb182907e5e0d14cf13ee81
DIST hypothesis-6.69.0.gh.tar.gz 9350681 BLAKE2B e28bca5be08809d7f10723186957ab72a650d93403fc0c5ed91b329ca3c68b084a69aba093e8dc7fdc742316287dc585b7b8794403e0b3fa29adfc7bf2d76ee7 SHA512 b6a263a10f78841706f6fa58a237f2f1e7ef5efd4d859e0fb79bae0ad3eff86774bc0cb7bb581af89605f80514a08386b5f501a6154bcc5ae1f56e7eb2ba61b4

77
dev-python/hypothesis/hypothesis-6.69.0.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
CLI_COMPAT=( python3_{9..10} )
PYTHON_COMPAT=( "${CLI_COMPAT[@]}" python3_11 pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
TAG=hypothesis-python-${PV}
MY_P=hypothesis-${TAG}
DESCRIPTION="A library for property based testing"
HOMEPAGE="
https://github.com/HypothesisWorks/hypothesis/
https://pypi.org/project/hypothesis/
"
SRC_URI="
https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
-> ${P}.gh.tar.gz
"
S="${WORKDIR}/${MY_P}/hypothesis-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' "${CLI_COMPAT[@]}")
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/requests-toolbelt-0.10.1
)
"
distutils_enable_tests pytest
python_test() {
# subtests are broken by warnings from random plugins
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
}
python_install() {
distutils-r1_python_install
if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
fi
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}