net-misc/nextcloud-client: add 4.0.1

Signed-off-by: Florian Schmaus <flow@gentoo.org>
2026-01-06 00:05:54 +03:00 · 2025-11-13 21:54:44 +01:00
parent 23c67dc99d
commit f297ca9250
2 changed files with 105 additions and 0 deletions
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -3,3 +3,4 @@ DIST nextcloud-client-3.15.2-fix-macosvfs-file-sharing.png.patch 727 BLAKE2B 77d
 DIST nextcloud-client-3.16.5.tar.gz 15684729 BLAKE2B f92f94c42025e845779cc08dabf8bb87a7ce06fe11d4147fc767e4a5330b81a10f8b7fe879cb5867fc3c395b7bbdafad64a7e4c70b39ef6e71c67a3377558bba SHA512 05685edbc89df1e27fa9d2c948caa3f4ca33c43772175e39835cb2e70f2447cf27192ec79c72a57d0e6bb6ae0348a207c5cf9806cd12b043a86aa565bd69221d
 DIST nextcloud-client-3.16.6.tar.gz 15690688 BLAKE2B ee53a332fc5ccace7e6ed3a4ddfccd04752eb342326420c97931958c27c3199f6e7143d7bde0c147f9c78d4f9b10e72d70a4f63775803a3a7be8ef656797ffb3 SHA512 f4ce295e2773731327faaef644a3d5e5371ff4bcc53f05ffcd00b476ddfc06a40c6684d1464d75885fac070f055030a9b69d76f5a002fcb8424d6bbb96afb291
 DIST nextcloud-client-3.17.2.tar.gz 9510476 BLAKE2B 4abac237ac74ddbe67203ef5c42498cf6526e0b76697f27fff95c0dea6b407c3a97d691010cbee30a5f7a4f77a42973808a4303060d7fe0d5ddc4649d0ec2e80 SHA512 46d392092cdda018062dbf012d74e7ea7efbcd38eac428daf2c568e909f52daf3344a519cfe665b24b5aca8a4b3492554d65ff3a39929847e657fba05ddfa1ce
+DIST nextcloud-client-4.0.1.tar.gz 8693203 BLAKE2B 6d4693a7a04162e82e5d2edff2b1e26172990a803202f3ed9e1137a4006e75b31b43e2513b72fa1b4a461102dbc121ad9c6c3fa55df2eb88f75f292594cf94cb SHA512 92bf454b60dcc4a3bfc27631361bcc61e69f0998c76f9e4bcf4e994d3ca81a3780ad67320b64eac0b0c2bacfce3974dff0224be01f3a4f7dd435adacf3057258
--- a/net-misc/nextcloud-client/nextcloud-client-4.0.1.ebuild
+++ b/net-misc/nextcloud-client/nextcloud-client-4.0.1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic qmake-utils virtualx xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="
+	https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz
+		-> ${P}.tar.gz
+"
+S="${WORKDIR}/desktop-${PV/_/-}"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="dolphin nautilus test webengine"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-db/sqlite-3.34:3
+	dev-libs/glib:2
+	dev-libs/libp11
+	>=dev-libs/openssl-1.1.0:0=
+	>=dev-libs/qtkeychain-0.14.2:=[qt6(+)]
+	dev-qt/qt5compat:6[qml]
+	>=dev-qt/qtbase-6.8:6[dbus,gui,network,sql,sqlite,ssl,widgets]
+	dev-qt/qtdeclarative:6[widgets]
+	dev-qt/qtsvg:6
+	dev-qt/qtwebsockets:6
+	kde-frameworks/karchive:6
+	kde-frameworks/kguiaddons:6
+	net-libs/libcloudproviders
+	virtual/zlib:=
+	dolphin? (
+		kde-frameworks/kcoreaddons:6
+		kde-frameworks/kio:6
+	)
+	nautilus? ( dev-python/nautilus-python )
+	webengine? ( dev-qt/qtwebengine:6[widgets] )
+"
+DEPEND="
+	${RDEPEND}
+	dev-qt/qtbase:6[concurrent,xml]
+	|| (
+		gnome-base/librsvg
+		media-gfx/inkscape
+	)
+	test? (
+		dev-util/cmocka
+	)
+"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	dolphin? ( >=kde-frameworks/extra-cmake-modules-5.106.0 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.6.6-no-redefine-fortify-source.patch
+)
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Temporary workaround for musl-1.2.4
+	# upstream bug: https://github.com/nextcloud/desktop/issues/6536
+	# gentoo bug #924503
+	# XXX: This will stop working with future musl releases!
+	use elibc_musl && append-cppflags -D_LARGEFILE64_SOURCE
+
+	local mycmakeargs=(
+		-DPLUGINDIR=$(qt6_get_plugindir)
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_UPDATER=OFF
+		-DBUILD_WITH_WEBENGINE=$(usex webengine)
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_SHELL_INTEGRATION_NAUTILUS=$(usex nautilus)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	TEST_VERBOSE=1 virtx cmake_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! has_version -r "dev-libs/qtkeychain[keyring]"; then
+		elog "dev-libs/qtkeychain has not been build with the 'keyring' USE flag."
+		elog "Please consider enabling the 'keyring' USE flag. Otherwise you may"
+		elog "have to authenticate manually every time you start the nextlcoud client."
+		elog "See https://bugs.gentoo.org/912844 for more information."
+	fi
+}