millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

dev-python/knowit: Bump to 0.5.8

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-07-27 05:24:37 +02:00
parent 4ed15580a6
commit fdd691d029
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
2 changed files with 72 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/knowit/Manifest
View File

@ -1,2 +1,3 @@
DIST knowit-0.5.6.gh.tar.gz 79683 BLAKE2B da132883e7b4d15a2a21b22b05cb627859947f293a4611a853b2bd31341e4b317a5de42bb7ab48b64a340d96327cb579bb7722f1e875dfc58d1e26652844064c SHA512 c064c2428300f0b2ee08e514e8deea2299f0aa9a552a7ac9ea914035e4e40666a21aa8d2256605d2c86c61592955f1e6b432d2cf43b7a34a3d1235d4b9971aaf
DIST knowit-0.5.8.tar.gz 59362 BLAKE2B 724b1f00bced9097059fbc798e75a872e347e2b00b5a9079172f7275f451d25f013afb9fd993775013a7a5181f29cdb4d7eb81eea22ff8d50a004c5f4ecd4ef0 SHA512 b6140e64f6a8295ac9fa811db1523c3a1c8aef686e3251f99bbc17e71ab9ddc9041bd4f8b8ed335691fb8fc4949da210f0bc95fbfcf7168045130f4357040b16
DIST matroska_test_w1_1.zip 184550509 BLAKE2B f111725aa08267661942072c2d4ac019d3d322c4e933aad10afb3aa6f69bb3469114c4400d161e53d8a7618b818b22465177460003804a7ac3e69fa4f4db000d SHA512 f170a8e83dab15228f992b3692330163da2402b8e436c7fa195ac1ecc06cf1eaf1a48d8c99a85c031122c158c2d4006023aae75d5b7805385ba25a6d601cb78f

71
dev-python/knowit/knowit-0.5.8.ebuild Normal file
View File

@ -0,0 +1,71 @@
# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=poetry
PYTHON_COMPAT=( python3_{11..14} )
inherit distutils-r1 pypi
DESCRIPTION="Know better your media files"
HOMEPAGE="
https://github.com/ratoaq2/knowit/
https://pypi.org/project/knowit/
"
SRC_URI+="
test? (
https://downloads.sourceforge.net/matroska/test_files/matroska_test_w1_1.zip
)
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
# https://github.com/ratoaq2/knowit/blob/d7135a4797440838bca94e76326fc9d4019d8f9a/README.md?plain=1#L224
RDEPEND="
>=dev-python/babelfish-0.6.1[${PYTHON_USEDEP}]
>=dev-python/enzyme-0.5.2[${PYTHON_USEDEP}]
>=dev-python/trakit-0.2.2[${PYTHON_USEDEP}]
>=dev-python/pymediainfo-7.0.1[${PYTHON_USEDEP}]
>=dev-python/pyyaml-6.0[${PYTHON_USEDEP}]
|| (
media-video/ffmpeg
media-video/mediainfo
media-video/mkvtoolnix
)
"
BDEPEND="
test? (
app-arch/unzip
>=dev-python/requests-2.32.4[${PYTHON_USEDEP}]
media-video/ffmpeg
media-video/mediainfo
media-video/mkvtoolnix
)
"
EPYTEST_PLUGINS=()
distutils_enable_tests pytest
src_unpack() {
# Needed to unpack the test data
default
if [[ ${PV} == 9999 ]] ; then
git-r3_src_unpack
fi
}
src_prepare() {
if use test ; then
mkdir -p tests/data/videos || die
ln -s "${WORKDIR}"/test*.mkv tests/data/videos/ || die
fi
distutils-r1_src_prepare
# poetry, sigh
sed -i -e 's:\^:>=:' pyproject.toml || die
}