add some media-sound packages

media-sound/morituri/Manifest

@@ -0,0 +1,3 @@
+DIST morituri-0.2.3.tar.bz2 265302 SHA256 20884da088392e8c2e89dda962e78714689ff80b8066fd2301f42be4835e60ac SHA512 35f734c90412765e74ef2a61a0ff30d1a783b5fc3e1c24a8cdf5a29bcde719cf775cf98110bb05a77f1d0e49566825f890db9b2cd7668099303450ef6913d556 WHIRLPOOL f04f673044a128a6f8dd02d1da40d24510c90443f0e67574d379d2323c50fa08e73b49119824ea1c4157647295faebfd9a2af2f3d4bfba522f5d693eb167436f
+EBUILD morituri-0.2.3.ebuild 1781 SHA256 b8fabe43d8ef39b602f7e75a707d8eaeb0c7b8d36af653c4ba281cba4128e1d3 SHA512 ee25c923cad7f41cbe3f8ebfab891b18675aff1a8be02d9b17c4b208a233cee3af36fc2aaa15db247a5369b3bf9e974242530961a8ba2737a2d5b85b30eedafe WHIRLPOOL b3c6f7735414a3e16b371d1765303c13f3e491d1783ff97b213a818d550979a832c101363ff8c16f0adf857dc348bb6a7dce262dcfc95365391985b115da16f8
+EBUILD morituri-9999.ebuild 1500 SHA256 6b65a4b1b607bb3e5eb18bced1bf3912722cdfa5b1372bcab6fa6ed4f7528658 SHA512 397483644e2806af8c48adc53911b3d27e6776a032b929983dc041f0fa866d0c52892aec718615c25cb65543e3918bb3104f67825119cc0116c186ee1d0e8e12 WHIRLPOOL 1d25b7bd9c90d1a3901fdb686bf03b19be96871c3cd5a9747d5881cca391f68f3578e6f4eced06d9fdb5da27e3f67f3edf20602049fca49de8e5e5210f2d609c

media-sound/morituri/morituri-0.2.3.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Tiziano Mueller
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit bash-completion-r1 python-single-r1
+
+DESCRIPTION="CD ripper aiming for accuracy over speed."
+HOMEPAGE="http://thomas.apestaart.org/morituri/trac/wiki"
+SRC_URI="http://thomas.apestaart.org/download/morituri/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="alac +cddb +cdio doc +flac test wav wavpack"
+
+RDEPEND="${PYTHON_DEPS}
+	media-sound/cdparanoia
+	app-cdr/cdrdao
+	media-libs/gstreamer
+	alac? ( media-plugins/gst-plugins-ffmpeg )
+	cddb? ( dev-python/cddb-py[${PYTHON_USEDEP}] )
+	cdio? ( dev-python/pycdio )
+	flac? ( media-plugins/gst-plugins-flac )
+	wav? ( media-libs/gst-plugins-good )
+	wavpack? ( media-plugins/gst-plugins-wavpack )
+	dev-python/gst-python:0.10[${PYTHON_USEDEP}]
+	dev-python/pygobject[${PYTHON_USEDEP}]
+	dev-python/pygtk[${PYTHON_USEDEP}]
+	dev-python/pyxdg[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/epydoc[${PYTHON_USEDEP}] )
+	test? ( dev-python/pychecker[${PYTHON_USEDEP}] )"
+
+src_prepare() {
+	# replace by fixed path to have it properly set by python_doscript
+	sed -i \
+		-e 's|@PYTHON@|/usr/bin/python|' \
+		bin/rip.in || die
+
+	# checks for .git and makes the install fail if not found
+	rm morituri/configure/uninstalled.py
+}
+src_configure() {
+	# disable doc building, we do it manually
+	export ac_cv_prog_EPYDOC=""
+	# disable automatic tests
+	export ac_cv_prog_PYCHECKER=""
+	default
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		cd doc
+		epydoc -o reference ../morituri || die "generating docs failed"
+	fi
+}
+
+src_install() {
+	default
+	python_doscript bin/rip
+
+	rm -rf "${D}/etc"
+	dobashcomp etc/bash_completion.d/rip
+
+	use doc && dohtml -r doc/reference/*
+}

media-sound/morituri/morituri-9999.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit bash-completion-r1 python-single-r1 eutils autotools git-2
+
+DESCRIPTION="A CD ripper aiming for accuracy over speed."
+HOMEPAGE="http://thomas.apestaart.org/morituri/trac/"
+
+EGIT_REPO_URI="git://github.com/thomasvs/morituri.git"
+EGIT_HAS_SUBMODULES=1
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="alac +cdio doc +cddb +flac test wav wavpack"
+
+RDEPEND="media-sound/cdparanoia
+	media-plugins/gst-plugins-cdparanoia
+	app-cdr/cdrdao
+	media-libs/gstreamer
+	>=media-libs/gst-plugins-base-0.10.22
+	alac? ( media-plugins/gst-plugins-ffmpeg )
+	cdio? ( dev-python/pycdio )
+	cddb? ( dev-python/cddb-py )
+	flac? ( media-plugins/gst-plugins-flac )
+	wav? ( media-libs/gst-plugins-good )
+	wavpack? ( media-plugins/gst-plugins-wavpack )
+	doc? ( dev-python/epydoc )
+	test? ( dev-python/pychecker )
+	dev-python/gst-python:0.10
+	dev-python/python-musicbrainz
+	dev-python/python-musicbrainz-ngs
+	dev-python/pygobject
+	dev-python/pygtk
+	dev-python/pyxdg"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	# disable doc building
+	local ac_cv_prog_EPYDOC=""
+
+	# disable test
+	local ac_cv_prog_PYCHECKER=""
+
+	default
+}
+
+src_install() {
+	default
+
+	python_doscript bin/rip
+
+	rm -rf "${D}/etc" || die
+	dobashcomp etc/bash_completion.d/rip
+
+	dodoc AUTHORS HACKING NEWS README RELEASE TODO
+
+	use doc && dohtml -r doc/reference/*
+}